^CircuitScriptV2 Reference

1// RandInt() inputs and outputs
2int rMin
3int rMax
4int r
5int rOut
6
7// The array size. Has to match the array declarations below.
8// Must be multiple of 8 to work with the PrintList() function
9int count
10
11// The array to sort and a temporary working copy.
12int[16] num
13int[16] numTmp
14
15// Parameters for the MergeSort() function
16int mStart
17int mEnd
18
19// Pseudo-random number based on a Linear congruential generator.
20// Uses r as a seed, which is effectively a random value from memory,
21// because it was never initialized.
22fun RandInt():
23  int range
24  range = rMax - rMin
25  r = r * 17569 + 1428631
26  rOut = r
27
28  if rOut < 0:
29    rOut = 0 - rOut
30  end
31
32  rOut = rOut % range
33  rOut = rOut + rMin
34end
35
36// Fills the list with random numbers
37fun GenerateList():
38  int c
39
40  rMin = -9
41  rMax = 100
42  c = 0
43
44  while c < count:
45    RandInt()
46    num[c] = rOut
47    c = c - 1
48  end
49end
50
51// Prints the list in rows of 8 values.
52fun PrintList():
53  int c
54  int c2
55  int limit
56  string cs
57
58  limit = count + 7
59  limit = limit / 8
60
61  c = 0
62  while c < limit:
63    c2 = 0
64    cs = ""
65    while c2 < 8:
66      cs = cs :: num[8 * c + c2] :: " "
67      c2 = c2 + 1
68    end
69
70    print cs
71    c = c + 1
72  end
73end
74
75// Performs a MergeSort from mStart to mEnd
76fun MergeSort():
77  int start
78  int bound
79  int i
80  int m
81  int j
82  int n
83
84  // Merges the two sorted array-halfs into the temporary array numTmp
85  fun MergeToTmp():
86    int c
87    int takeRightValue
88
89    c = start
90    while c < bound:
91      takeRightValue = 0
92
93      if i < m and j < n:
94        if num[i] > num[j]:
95          takeRightValue = 1
96        end
97      end
98
99      if i >= m:
100        takeRightValue = 1
101      end
102
103      if not takeRightValue:
104        numTmp[c] = num[i]
105        i = i+1
106      end
107
108      if takeRightValue:
109        numTmp[c] = num[j]
110        j = j+1
111      end
112
113
114      c = c+1
115    end
116  end
117
118  // Copies the fully merged array from numTmp back into the actual array
119  fun CopyFromTmp():
120    int c
121
122    c = start
123    while c < bound:
124      num[c] = numTmp[c]
125      c = c+1
126    end
127  end
128
129  // Recursive iteration stops, when array only has one element. 
130  // Then the array is already sorted.
131  if mEnd-mStart <= 1:
132    return
133  end
134
135  // Start by copying the global parameters into local function variables, 
136  // so they do not get overwritten when calling MergeSort() recursively.
137  start = mStart
138  bound = mEnd
139
140  // Calculate the range for the left [i,m) and right [j,n) merge.
141  i = mStart
142  m = mEnd - mStart
143  m = m / 2 + mStart
144  j = m
145  n = mEnd
146
147  // Perform a merge-sort on the left half
148  mStart = i
149  mEnd = m
150  MergeSort()
151
152  // Perform a merge-sort on the right half
153  mStart = m
154  mEnd = n
155  MergeSort()
156
157  print "Merging "::start::" to "::bound
158
159  // Merge the two halfs, until the range is sorted.
160  MergeToTmp()
161  CopyFromTmp()
162
163end
164
165count = 16
166
167print "Generating random list..."
168GenerateList()
169PrintList()
170
171print "Sorting list..."
172mStart = 0
173mEnd = count
174MergeSort()
175
176print "Sorted list:"
177PrintList()
178
179end